home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Libris Britannia 4
/
science library(b).zip
/
science library(b)
/
PROGRAMM
/
PROGEDIT
/
3458B.ZIP
/
AMAC44B.ZIP
/
TIM002.QM
< prev
next >
Wrap
Text File
|
1991-08-03
|
4KB
|
82 lines
* TIM002.QM
* Written By Tom Hogshead
* [ See TIMERxx.QM For Use ]
* August 2, 1991
* Key Subfile
* ===== ========= =====================================================
* @(2) --Times Macro Command Sequences For ONE Repeat Only
* (Inserted_In) @2
* {e:\up\TIMER14}--Return To TIMERxx.QM
*
*-- eoi
*
* ----------------------------------------------------------------------
* @(2) Measures Running Time of Macro Command Sequences, ONE Repeat Only
* 146 bytes Sun 07-07-1991 17:47:19 (TH @2)
* ----------------------------------------------------------------------
* @2 is used to time single repeats. It gives identical time
* measurements for single repeats with @1, but is a bit simpler and
* easier to modify by the user, if desired. It is also useful for
* timing "slow" command sequences. Macro command sequences to be timed
* with @2 may not require a block to be marked before execution,
* otherwise it will be unmarked by @2 at the first unmarkblock. Blocks
* may be marked and/or unmarked during execution of the inserted
* command sequences. The cursor must be returned to the line the macro
* was started on for the timing record to remain on the same line. @q
* is a simpler version that does not have these limitations and is
* almost "foolproof".
* Base Time = 0.30 secs/repeat (30 repeats timed)
@2 macrobegin
unmarkblock defaultwordset *
setrmargin "80" return * For timer messages on same line |
insertline begline *
"Cycle [Y=yes, Enter=no] ?" *
cursorright dropanchor *
Pause *
storescrbuff "1" return * Y, or Enter for only one cycle
delline *
insertline * |
CYCLE: *
gotocolumn "41" return *
dropanchor begline *
fillblock "*" return * Insert start line
unmarkblock
insertline *
"*" gotocolumn "41" return "*" * Insert starting line of stars
cursorright *
* ■■■■■ Timing Starts Here ■■■■■ *
Insert_Time * Insert start time
TIME:* * No looping
* **** <Commands to Time (Inserted_In) @2 Here> ****
Cursorright * Position for end time
Insert_Time * Insert end time
* ■■■■■ Timing Ends Here ■■■■■ *
prevposition * Move to first char of time
delrtword delch * Delete 'Hour:'
endline cursorright cursorright *
insertdate * Insertdate
wordleft delch delch * Delete 91
wordleft wordleft wordleft *
delrtword * Delete day of week
endline cursorright "@2 " *
"1!" *
begline *
getscrbuff "1" return *
endline * Test if answered 'y' to cycle
jfalse END: * If true, are at eol, cycle again
delline * Delete buff 1 line
insertline * Insert line for next cycle
jump CYCLE: *
END: *
unmarkblock delline * Cleanup
begline cursorright cursorright * Position cursor to calculate time
*
* 147 bytes Fri 06-28-1991 12:13:39 (TH @2)
* 141 bytes Sun 06-30-1991 22:43:30 (TH @2 removed currentfilename/copy)
* 146 bytes Sun 07-07-1991 17:47:19 (TH @2 add insertline, setrtmargin "80")